OUTPUT_FORMAT("elf64-ia64-little", "elf64-ia64-little", "elf64-ia64-little")
OUTPUT_ARCH(ia64)
ENTRY(start)
kernel_text = 0xe000000004000000;
SECTIONS
{
  . = kernel_text + SIZEOF_HEADERS;
  PROVIDE (btext = .);
  .plt : { *(.plt) }
  .text :
  {
    *(.text .stub .text.* .gnu.linkonce.t.*)
    *(.gnu.warning)
  } =0x00300000010070000002000001000400
  _etext = .;
  PROVIDE (etext = .);
  .rodata : { *(.rodata .rodata.* .gnu.linkonce.r.*) }
  .rodata1 : { *(.rodata1) }
  .sdata2 : { *(.sdata2 .sdata2.* .gnu.linkonce.s2.*) }
  .sbss2 : { *(.sbss2 .sbss2.* .gnu.linkonce.sb2.*) }
  .opd : { *(.opd) }
  .IA_64.unwind_info : { *(.IA_64.unwind_info* .gnu.linkonce.ia64unwi.*) }
  .IA_64.unwind : { *(.IA_64.unwind* .gnu.linkonce.ia64unw.*) }
  . = . + 8192;
  .data :
  {
    *(.data.proc0 .data .data.* .gnu.linkonce.d.*)
    SORT(CONSTRUCTORS)
  }
  .data1 : { *(.data1) }
  .dynamic : { *(.dynamic) }
  . = ALIGN(16);
  __gp = . + 0x200000;
  .got : { *(.got.plt) *(.got) }
  .IA_64.pltoff : { *(.IA_64.pltoff) }
  .sdata :
  {
    *(.sdata .sdata.* .gnu.linkonce.s.*)
  }
  _edata = .;
  PROVIDE (edata = .);
  __bss_start = .;
  .sbss :
  {
    PROVIDE (__sbss_start = .);
    PROVIDE (___sbss_start = .);
    *(.dynsbss)
    *(.sbss .sbss.* .gnu.linkonce.sb.*)
    *(.scommon)
    PROVIDE (__sbss_end = .);
    PROVIDE (___sbss_end = .);
  }
  .bss :
  {
    *(.dynbss)
    *(.bss .bss.* .gnu.linkonce.b.*)
    *(COMMON)
    . = ALIGN(64 / 8);
  }
  . = ALIGN(64 / 8);
  _end = .;
  PROVIDE (end = .);
}