# Copyright 2020-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

CRATES="
	openssl@0.10.78
	openssl-sys@0.9.114
"
inherit cargo

DESCRIPTION="Command-line client for WebSockets, like netcat, with socat-like functions"
HOMEPAGE="https://github.com/vi/websocat"
SRC_URI="https://github.com/vi/websocat/archive/v${PV}.tar.gz -> ${P}.tar.gz"
SRC_URI+=" https://github.com/gentoo-crate-dist/${PN}/releases/download/v${PV}/${P}-crates.tar.xz"
SRC_URI+=" ${CARGO_CRATE_URIS}"

LICENSE="MIT"
# Dependent crate licenses
LICENSE+=" Apache-2.0 BSD-2 BSD ISC MIT Unicode-DFS-2016"
SLOT="0"
KEYWORDS="~amd64"
IUSE="ssl"
RESTRICT+=" test"

RDEPEND="
	ssl? ( dev-libs/openssl:0= )
"
DEPEND="${RDEPEND}"

QA_FLAGS_IGNORED="/usr/bin/websocat"

PATCHES=(
	"${FILESDIR}"/${P}-openssl-4.patch
)

src_configure() {
	local myfeatures=(
		$(usev ssl)
		seqpacket
		signal_handler
		tokio-process
		unix_stdio
	)
	cargo_src_configure --no-default-features
}

src_install() {
	cargo_src_install
	dodoc *.md
}