# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

GENTOO_DEPEND_ON_PERL="no"
QA_PKGCONFIG_VERSION=$(ver_cut 1-3)
inherit autotools flag-o-matic perl-module toolchain-funcs

DESCRIPTION="A collection of tools and libraries for many image formats"
HOMEPAGE="https://imagemagick.org"

if [[ ${PV} == 9999 ]] ; then
	EGIT_REPO_URI="https://github.com/ImageMagick/ImageMagick.git"
	inherit git-r3
	MY_P="imagemagick-9999"
else
	VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/imagemagick.asc
	inherit verify-sig

	MY_PV="$(ver_rs 3 '-')"
	MY_P="ImageMagick-${MY_PV}"
	SRC_URI="
		mirror://imagemagick/${MY_P}.tar.xz
		verify-sig? ( mirror://imagemagick/${MY_P}.tar.xz.asc )
	"

	KEYWORDS="~alpha amd64 arm arm64 ~hppa ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 ~sparc x86 ~arm64-macos ~x64-macos ~x64-solaris"
	BDEPEND="verify-sig? ( sec-keys/openpgp-keys-imagemagick )"
fi

S="${WORKDIR}/${MY_P}"

LICENSE="imagemagick"
# Please check this on bumps, SONAME is often not updated! Use abidiff on old/new.
# If ABI is broken, change the bit after the '-'.
SLOT="0/$(ver_cut 1-3)-18"
IUSE="bzip2 corefonts +cxx djvu fftw fontconfig fpx graphviz hardened hdri heif"
IUSE+=" jbig jpeg jpeg2k jpegxl lcms lqr lzma opencl openexr openmp pango perl ${GENTOO_PERL_USESTRING}"
IUSE+=" +png postscript q32 q8 raw static-libs svg test tiff truetype webp wmf"
IUSE+=" X xml zip zlib"

REQUIRED_USE="
	corefonts? ( truetype )
	svg? ( xml )
	test? ( corefonts )
"

RESTRICT="!test? ( test )"

RDEPEND="
	!media-gfx/graphicsmagick[imagemagick]
	dev-libs/libltdl
	bzip2? ( app-arch/bzip2 )
	corefonts? ( media-fonts/corefonts )
	djvu? ( app-text/djvu )
	fftw? ( sci-libs/fftw:3.0 )
	fontconfig? ( media-libs/fontconfig )
	fpx? ( >=media-libs/libfpx-1.3.0-r1 )
	graphviz? ( media-gfx/graphviz )
	heif? ( media-libs/libheif:=[x265] )
	jbig? ( >=media-libs/jbigkit-2:= )
	jpeg? ( media-libs/libjpeg-turbo:= )
	jpeg2k? ( >=media-libs/openjpeg-2.1.0:2 )
	jpegxl? ( >=media-libs/libjxl-0.6:= )
	lcms? ( media-libs/lcms:2= )
	lqr? ( media-libs/liblqr )
	opencl? ( virtual/opencl )
	openexr? ( media-libs/openexr:0= )
	pango? ( x11-libs/pango )
	perl? (
		${GENTOO_PERL_DEPSTRING}
		>=dev-lang/perl-5.8.8:=
	)
	png? ( media-libs/libpng:= )
	postscript? ( app-text/ghostscript-gpl:= )
	raw? ( media-libs/libraw:= )
	svg? (
		gnome-base/librsvg
		media-gfx/potrace
	)
	tiff? ( media-libs/tiff:= )
	truetype? (
		media-fonts/urw-fonts
		>=media-libs/freetype-2
	)
	webp? ( media-libs/libwebp:= )
	wmf? ( media-libs/libwmf )
	X? (
		x11-libs/libICE
		x11-libs/libSM
		x11-libs/libXext
		x11-libs/libXt
	)
	xml? ( dev-libs/libxml2:= )
	lzma? ( app-arch/xz-utils )
	zip? ( dev-libs/libzip:= )
	zlib? ( virtual/zlib:= )
"
DEPEND="
	${RDEPEND}
	X? ( x11-base/xorg-proto )
"
BDEPEND+=" virtual/pkgconfig"

PATCHES=(
	"${FILESDIR}/${PN}-9999-nocputuning.patch"
)

pkg_pretend() {
	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
}

pkg_setup() {
	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
}

src_prepare() {
	default

	#elibtoolize # for Darwin modules
	eautoreconf

	# For testsuite, see bug #500580#c3
	shopt -s nullglob
	for card in /dev/{{ati,dri}/card,nvidia,dri/renderD128}*; do
		addpredict "${card}"
	done
	shopt -u nullglob
	addpredict /dev/nvidiactl
}

src_configure() {
	local depth=16
	use q8 && depth=8
	use q32 && depth=32

	use perl && perl_check_env

	[[ ${CHOST} == *-solaris* ]] && append-ldflags -lnsl -lsocket

	local myeconfargs=(
		$(use_enable static-libs static)
		$(use_enable hdri)
		$(use_enable opencl)
		$(use_enable openmp)
		--with-threads
		--with-modules
		--with-quantum-depth=${depth}
		$(use_with cxx magick-plus-plus)
		$(use_with perl)
		--with-perl-options='INSTALLDIRS=vendor'
		--with-gs-font-dir="${EPREFIX}"/usr/share/fonts/urw-fonts
		$(use_with bzip2 bzlib)
		$(use_with X x)
		$(use_with zip)
		$(use_with zlib)
		--without-autotrace
		--with-uhdr
		$(use_with postscript dps)
		$(use_with djvu)
		--with-dejavu-font-dir="${EPREFIX}"/usr/share/fonts/dejavu
		$(use_with fftw)
		$(use_with fpx)
		$(use_with fontconfig)
		$(use_with truetype freetype)
		$(use_with postscript gslib)
		$(use_with graphviz gvc)
		$(use_with heif heic)
		$(use_with jbig)
		$(use_with jpeg)
		$(use_with jpeg2k openjp2)
		$(use_with jpegxl jxl)
		$(use_with lcms)
		$(use_with lqr)
		$(use_with lzma)
		$(use_with openexr)
		$(use_with pango)
		$(use_with png)
		$(use_with raw)
		$(use_with svg rsvg)
		$(use_with tiff)
		$(use_with webp)
		$(use_with corefonts windows-font-dir "${EPREFIX}"/usr/share/fonts/corefonts)
		$(use_with wmf)
		$(use_with xml)

		# Default upstream (as of 6.9.12.96/7.1.1.18 anyway) is open
		# For now, let's make USE=hardened do 'limited', and have USE=-hardened
		# reflect the upstream default of 'open'.
		#
		# We might change it to 'secure' and 'limited' at some point.
		# See also bug #716674.
		--with-security-policy=$(usex hardened limited open)
	)

	CONFIG_SHELL="${BROOT}"/bin/bash econf "${myeconfargs[@]}"
}

src_compile() {
	# Avoid perl-module_src_compile
	default
}

src_test() {
	# Install default (unrestricted) policy for the test suite, bug #664238
	#
	# IM has to be coerced into not looking at the system policy.xml
	# last. With this, it will look at the one in ${S}/config, the system
	# one if it exists, then our generous one for tests.
	local -x XDG_CONFIG_HOME="${T}"
	local -x MAGICK_HOME="${T}"/ImageMagick
	local -x MAGICK_CONFIGURE_PATH="${T}"/ImageMagick

	mkdir "${XDG_CONFIG_HOME}"/ImageMagick || die
	mv "${S}"/config/policy.xml{,.bak} || die
	cp "${S}"/config/policy{-open,}.xml || die
	cp "${FILESDIR}"/policy.test.xml "${XDG_CONFIG_HOME}"/ImageMagick/policy.xml || die

	local ret=0
	(
		# Make sure we use the just-built IM
		. "${S}"/magick.sh
		nonfatal emake check
	) || ret=$?

	mv "${S}"/config/policy.xml{.bak,} || die
	(( ${ret} == 0 )) || die "emake check failed"
}

src_install() {
	# Ensure documentation installation files and paths with each release!
	emake \
		DESTDIR="${D}" \
		DOCUMENTATION_PATH="${EPREFIX}"/usr/share/doc/${PF}/html \
		install

	einstalldocs

	if use perl; then
		find "${ED}" -type f -name perllocal.pod -exec rm -f {} + || die
		find "${ED}" -depth -mindepth 1 -type d -empty -exec rm -rf {} + || die
	fi

	# .la files in parent are not needed, keep plugin .la files
	find "${ED}"/usr/$(get_libdir)/ -maxdepth 1 -name "*.la" -delete || die

	# https://github.com/gentoo/gentoo/pull/37716#discussion_r1696713348
	find "${ED}" -name '*.la' -exec sed -i -e "/^dependency_libs/s:=.*:='':" {} + || die

	if use opencl; then
		cat <<-EOF > "${T}"/99${PN} || die
		SANDBOX_PREDICT="/dev/nvidiactl:/dev/nvidia-uvm:/dev/ati/card:/dev/dri/card:/dev/dri/card0:/dev/dri/renderD128"
		EOF

		insinto /etc/sandbox.d
		doins "${T}"/99${PN} #472766
	fi

	insinto /usr/share/${PN}
	doins config/*icm
}